Godot4 ビッグカツブロック崩し2８ セーブデータを管理するスクリプト例

extends Node
class_name SaveData
## セーブデータを管理するクラスです。プロジェクト設定の自動読み込みに設定しているグローバルなノードです。
## 以前に作成した TapTheTakarabako の記事も参照にしてください。
## https://compota-soft.work/archives/25627

## ベストタイム（ゲームクリアの最速タイム）です。
## -1 (0 未満) の場合は、まだ一度もクリアしていないので記録がない状態です。
var best_time: float = -1.0

## 音量です。 0.0 ~ 1.0 を指定します。
## タイトルのシーンの $HSliderSoundVolume スライダーで調整します。
var sound_volume: float = 0.5

## セーブデータの保存先です。
## Windows の場合は、このパスで使われている user:// は
## "%APPDATA%\Godot\app_userdata\プロジェクト名\" を指します。
var save_path = "user://BigBreakOut.save"

# Called when the node enters the scene tree for the first time.
func _ready():
	# オートロード（自動読み込み）でゲーム起動時に SaveDataGlobal ノードが root の下に配置される際に
	# 呼び出され、ゲーム起動直後にセーブデータを読み込みます。セーブデータがない場合はそれに対応する変数を初期化します。
	load_app_data()
	return

## セーブデータを保存します。
## F6 キーで保存されない場合、 F5 キーで実行するとロードとセーブができるかもしれません。
## プレイ中の BestTime のラベルの表示を更新するには ステージのシーンの $BestTime.update_label() を呼び出してください。
func save_app_data()->void:
	# セーブデータの変数を作成して、保存したい項目を設定します。
	var save_data = {}
	save_data["best_time"] = best_time	# スコア
	save_data["sound_volume"] = sound_volume # 音量
	
	# セーブファイルを書き込みモードで開きます。
	var f = FileAccess.open(save_path, FileAccess.WRITE)	
	# セーブデータの変数を文字列に変換して、セーブファイルに書きます。
	var s = var_to_str(save_data)
	f.store_string(s)	
	# ファイルを閉じます。
	f.close()
	return

## セーブデータをロードします。なければ既定値で初期化します。
## プレイ中の BestTime のラベルの表示を更新するには ステージのシーンの $BestTime.update_label() を呼び出してください。
func load_app_data()->void:
	var save_data: Dictionary

	# セーブファイルが存在する場合
	if FileAccess.file_exists(save_path):
		# ファイルを読み込み、セーブデータを変数に格納します。
		var f = FileAccess.open(save_path, FileAccess.READ)
		var s = f.get_as_text()
		save_data = str_to_var(s)
		# 使った後に、ファイルを閉じます。
		f.close()
	
	# 読み込んだセーブデータをメンバ変数や UI の値に反映します。
	# そのキーがない場合は、初期値を設定します。
	#   ベストタイム
	if not save_data.has("best_time"):
		save_data["best_time"] = -1.0
	best_time = save_data["best_time"]
	#   音量
	if not save_data.has("sound_volume"):
		save_data["sound_volume"] = 0.5
	sound_volume = save_data["sound_volume"]
	return

## ベストタイムを初期化します。
## プレイ中の BestTime のラベルの表示を更新するには ステージのシーンの $BestTime.update_label() を呼び出してください。
func init_best_time()->void:
	best_time = -1	# ベストタイムを初期値に変更します。
	save_app_data()	# セーブします。
	return

## ベストタイムのセーブデータを更新します。
## [param time] が [member best_time] より大きい（遅いタイム）の場合は更新しません。
func update_best_time_save_data(time: float)->void:
	if best_time < 0 or (best_time >= 0 and best_time > time):
		best_time = time	# タイムを更新します。
		save_app_data()	# セーブします。
	return

## 音量調節のスライダーからフォーカスが外れた際に、その音量をセーブします。
func _on_h_slider_sound_volume_focus_exited():
	# スライダー UI の現在選択されている音量の値(0.0 ~ 1.0) を取得して、セーブデータの変数を更新します。
	$"/root/SaveDataGlobal".sound_volume = $HSliderSoundVolume.value
	# セーブデータを保存します。
	$"/root/SaveDataGlobal".save_app_data()
	return