Godot4 独自ツールメニューの実行前後に戻す undo, redoの実装例

@tool
extends EditorPlugin
## 選択されているノード群にテキストを持ったコントロールがある場合に、
## コントロールのサイズからはみ出ない最大のサイズにフィットしたフォントサイズに自動調節するエディタ拡張です。
## メニュー「プロジェクト」→「ツール」に追加されたメニューアイテムを選択することで実行されます。

## メニューアイテムの表示名です。
var tool_menu_item_name: StringName = "Sc Fit Font Size"

## プラグインの初期化処理を定義します。
## プラグイン (プロジェクト設定ダイアログ＞プラグイン＞有効) を有効にした直後や、プラグインが有効な状態のプロジェクトを開いた際に呼び出されます。
func _enter_tree():
	# Initialization of the plugin goes here.
	# メニュー「プロジェクト」→「ツール」にサブメニューを追加します。メニュー選択時に、第二引数のメンバ関数を呼び出します。
	add_tool_menu_item(tool_menu_item_name, Callable(self, "_on_menu_item_sc_fit_font_size"))
	print("sc_fit_font_size.gd: _enter_tree called")

## プラグインの後片付けの処理を定義します。
## プラグインを無効 (プロジェクト設定ダイアログ＞プラグイン＞有効) にした直後や、プラグインが有効な状態のプロジェクトを閉じた際に呼び出されます。
func _exit_tree():
	# Clean-up of the plugin goes here.
	# 
	remove_tool_menu_item(tool_menu_item_name)
	print("sc_fit_font_size.gd: _exit_tree called")

# EditorPlugin で Undo, Redo を実装する主な流れです。
# 例として選択しているノード（１番目）の名前を Piyo に変更する処理の実行, Redo と、元の名前に戻す Undo を実装します。
func _on_menu_item_sc_fit_font_size() -> void:
	# 例として、操作対象に選択中のノードの１番目を選びます。 self は EditorPlugin クラスです。
	var editor_interface: EditorInterface = self.get_editor_interface()
	var editor_selection: EditorSelection = editor_interface.get_selection()
	var selected_nodes: Array[Node] = editor_selection.get_selected_nodes()
	if selected_nodes.size() < 1:
		# 選択しているノードがない場合は何もしません。
		return
	var target_node: Node = selected_nodes[0]
	
	# 例として、ノードの名前を変更します。 Undo では、元の名前に戻します。
	var action_name: StringName = "Rename Node Piyo"
	var property_name: StringName = "name"
	var old_name: StringName = target_node.name
	var new_name: StringName = "Piyo"


	# Undo, Redo 操作を実装するためのオブジェクトです。
	var editor_undo_redo_manager: EditorUndoRedoManager = get_undo_redo()

	# アクションを登録します。
	editor_undo_redo_manager.create_action(action_name)
	
	# ----- ↓ 今回のアクションで実行するコマンド、元に戻すためのコマンドをを 1 個以上登録します ----
	# 実行（または redo）する際に、指定したオブジェクトのプロパティの値の変更のコマンドを追加します。
	editor_undo_redo_manager.add_do_property(target_node, property_name, new_name)
	# undo する際に、指定したオブジェクトのプロパティの値をもとに戻すコマンドを追加します。
	editor_undo_redo_manager.add_undo_property(target_node, property_name, old_name)

	# 他にも、add_do_method, add_undo_method でメンバ関数呼び出しを登録できます。
	# プロパティの変更と異なる処理を行う場合に使用します。
	# 
	# また実行 (do) や元に戻す処理 (undo) が巻き戻差れた際に消えてしまうオブジェクトを保持する
	# add_do_reference, add_undo_reference メンバ関数もあります。
	
	# ----- ↑ 今回のアクションで実行するコマンド、元に戻すためのコマンドをを 1 個以上登録しました ----

	# add_do_* 系の関数を全て実行します。
	# あとで Undo の指示がきた場合は、add_undo_* 系の関数で登録したコマンドが実行されます
	editor_undo_redo_manager.commit_action()
	return

Rename Node Piyo
シーン元に戻す: Rename Node Piyo
シーンやり直す: Rename Node Piyo