Godot4 Config ファイルのデータを辞書変数にロードする関数の例

extends Node
## ConfigFile のセクションの読み書きを Dictionary 型を用いて行う関数とそのテストです。
## F6 キーでこのスクリプトを割り当てたシーンを実行すると起動直後にテストが実行されます。

# Called when the node enters the scene tree for the first time.
func _ready():
	test_load_config_file_section_to_dictionary()
	return


## load_config_file_section_to_dictionary のテスト関数です。
func test_load_config_file_section_to_dictionary():
	## 以下のパスに .cfg ファイルが作成されます。
	const CONFIG_FILE_PATH = "res://study/config_file/sample.cfg"
	const CONFIG_FILE_SECTION = "scale_correction_value"
	
	## セクション内に保存されるデータです。
	var dic_answer = {}
	dic_answer["Label"] = 0.9
	dic_answer["Button"] = 1.0
	
	# 辞書のデータ群を、指定した Config ファイルのセクションに保存します。
	# ファイルが存在しない場合は作成し、存在する場合は辞書の要素ごとに上書きします。
	print("save_config_file_section_from_dictionary call")
	save_config_file_section_from_dictionary(
		CONFIG_FILE_PATH, CONFIG_FILE_SECTION, dic_answer)
	
	## 指定した Config ファイルのセクションを読み込み、辞書として取得します。
	print("load_config_file_section_to_dictionary call")
	var dic: Dictionary = load_config_file_section_to_dictionary(
		CONFIG_FILE_PATH, CONFIG_FILE_SECTION)
	
	# 保存した辞書の内容と、読み込んだ辞書の内容が等しいことを確認します。
	# 異なる場合は警告を出力します。
	if dic != dic_answer:
		push_warning("study_config_file_to_dictionary.gd:" +
			"test_load_sample_dictionary:" +
			"dic != dic_answer")
	
	# デバッグ用。読み込んだ辞書の内容を出力します。
	var str_dic: String = ScUtil.to_pretty_print_string(dic)
	print(str_dic)

	return


## 指定した .cfg ファイルのセクションを辞書型で取得します。
func load_config_file_section_to_dictionary(
	path: String, section: String) -> Dictionary:
	
	var dic := {}
	var config_file := ConfigFile.new()
	
	var err := config_file.load(path)
	if err != OK:
		push_warning("study_config_file_to_dictionary.gd:" +
			"load_config_file_section_to_dictionary:" +
			"config_file.load(path) != OK")
		return dic
	
	if config_file.has_section(section) == false:
		push_warning("study_config_file_to_dictionary.gd:" +
			"load_config_file_section_to_dictionary:" +
			"config_file.has_section(section) == false")
		return dic
	
	for key in config_file.get_section_keys(section):
		dic[key] = config_file.get_value(section, key)
	
	return dic


## 指定した .cfg ファイルのセクションに、辞書型のデータを保存します。
## 辞書の要素のキーは、ConfigFile.set_value の key 引数、値は value 引数に対応します。
func save_config_file_section_from_dictionary(
	path: String, section: String, dic: Dictionary) -> void:
	
	# セーブする dic の要素を１つずつ config_file に設定します。
	var config_file := ConfigFile.new()
	for key in dic.keys():
		config_file.set_value(section, key, dic[key])
	
	# Config ファイルに保存します。
	var err = config_file.save(path)
	if err != OK:
		push_error("study_config_file_to_dictionary.gd:" +
			"save_config_file_section_from_dictionary:" +
			"config_file.save(path) != OK, path = ", path)
	
	return

	dic_answer["Label"] = 0.9
	dic_answer["Button"] = 1.0

save_config_file_section_from_dictionary call
load_config_file_section_to_dictionary call
{
	"Label": 0.9,
	"Button": 1
}

--- Debugging process stopped ---