Godot4 選択ノードの解除・再選択・ルートノードの選択追加のスクリプト例

extends Object
class_name SakuraCrowdUtil

## [method EditorPlugin._handles] イベント関数がシステムから呼び出されるように促します。
## 方法として、選択中のノードの再選択([method SakuraCrowdUtil.reselect_nodes])、
## 選択されていない場合はルートノードの選択([method SakuraCrowdUtil.add_root_node_to_selection])を行います。
## いずれかの方法を行った場合は true, それ以外は false を返します。
static func request_call_editor_plugin_handles_event(editor_plugin: EditorPlugin) -> bool:
	if reselect_nodes(editor_plugin) == false:
		if add_root_node_to_selection(editor_plugin) == false:
			print("SakuraCrowdUtil.request_call_editor_plugin_handles_event: 何も行いませんでした。")
			return false
		else:
			print("SakuraCrowdUtil.request_call_editor_plugin_handles_event: add_root_node_to_selection を行いました。")
	else:
		print("SakuraCrowdUtil.request_call_editor_plugin_handles_event: reselect_nodes を行いました。")
	return true

## 現在選択されているノード群を一度解除してから再び選択します。
## 選択されているノードがない場合はルートノードを再び選択します。
## ルートノードがない場合は何もしません。
## 再選択を行った場合は true, それ以外は false を返します。
static func reselect_nodes(editor_plugin: EditorPlugin) -> bool:
	var editor_interface: EditorInterface = editor_plugin.get_editor_interface()
	
	# すべての選択中のノードの選択を解除して、そのノード群を取得します。
	var deselected_nodes: Array[Node] = deselect_nodes(editor_plugin)
	
	if deselected_nodes.size() > 0:
		# 選択解除したノード群を再選択します。
		for node in deselected_nodes:
			editor_interface.get_selection().add_node(node)
		print("SakuraCrowdUtil.reselect_nodes: 選択中のノードを再選択しました。")
		return true
	return false

## 選択中のノード群を解除します。
## 解除したノード群の配列を返します。配列の要素数 size() は 0 かもしれません。
static func deselect_nodes(editor_plugin: EditorPlugin) -> Array[Node]:
	var editor_interface: EditorInterface = editor_plugin.get_editor_interface()
	
	# 選択中のノード群を取得します。
	var selected_nodes: Array = editor_interface.get_selection().get_selected_nodes()
	
	# 選択中のノードを１つずつ解除します。
	if selected_nodes.size() > 0:
		for node in selected_nodes:
			editor_interface.get_selection().remove_node(node)
		print("SakuraCrowdUtil.deselect_nodes: 選択中のノードを選択解除しました。")
	
	return selected_nodes

## ルートノードを選択中のノードに追加します。
## 追加した場合は true, それ以外は false を返します。
static func add_root_node_to_selection(editor_plugin: EditorPlugin) -> bool:
	var editor_interface: EditorInterface = editor_plugin.get_editor_interface()
	
	# 選択されているノードがない場合、ルートノードを再選択します。
	var scene_tree: SceneTree = editor_plugin.get_tree()
	var root_node: Node = scene_tree.edited_scene_root
	if root_node:
		editor_interface.get_selection().add_node(root_node)
		print("SakuraCrowdUtil.add_root_node_to_selection: ルートノードを選択しました。")
		return true
	else:
		print("SakuraCrowdUtil.add_root_node_to_selection: ノードが選択されていませんでしたし、ルートノードもありませんでした。")
	return false

## ユーザーがプロジェクト設定ウィンドウの [プラグイン] タブで EditorPlugin を有効にすると、エンジンによって呼び出されます。
func _enable_plugin():
	print("_enable_plugin called")
	# 有効になった直後に、 _handles イベント関数の呼び出しを促します。
	SakuraCrowdUtil.request_call_editor_plugin_handles_event(self)
	return