Godot4 EditorSettings 既定値を指定した設定値の取得の例

@tool
extends EditorPlugin

## EditorSettings の「ユーザ名/アドオン名/セクション名/キー」の読み書きを Dictionary 型を用いて行う関数とそのテストです。
## EditorInterface の機能はエディタ上で利用できます。
## EditorSettings の機能を含む関数を実行するために、プラグインとしてこのスクリプトを追加して
## ツールメニュー（「プロジェクト」→「ツール」）から、これが追加したメニューを選択してください。
## 
## EditorSettings のファイルは C:\Users\ユーザ名\AppData\Roaming\Godot\editor_settings-4.3.tres にあります。
## 4.3 の部分はバージョンによって変わります。

## メニューアイテムの表示名です。
const tool_menu_item_name: StringName = "Study EditorSettings By Dictionary"

## プラグインの初期化処理を定義します。
## プラグイン (プロジェクト設定ダイアログ＞プラグイン＞有効) を有効にした直後や、プラグインが有効な状態のプロジェクトを開いた際に呼び出されます。
func _enter_tree():
	# Initialization of the plugin goes here.
	# メニュー「プロジェクト」→「ツール」にサブメニューを追加します。メニュー選択時に、第二引数のメンバ関数を呼び出します。
	add_tool_menu_item(tool_menu_item_name, Callable(self, "_on_menu_item_study_editor_settings_by_dictionary"))
	return


## プラグインの後片付けの処理を定義します。
## プラグインを無効 (プロジェクト設定ダイアログ＞プラグイン＞有効) にした直後や、プラグインが有効な状態でプロジェクトを閉じた際に呼び出されます。
func _exit_tree():
	# Clean-up of the plugin goes here.
	remove_tool_menu_item(tool_menu_item_name)
	return


## プラグインで追加したツールメニューを選択した際に呼び出される関数です。
func _on_menu_item_study_editor_settings_by_dictionary():
	test_load_editor_settings_section_to_dictionary()
	return


func test_save_editor_settings_section_from_dictionary():
	# 以下の 2 つを組み合わせて、さらにキー名を追加した name で辞書変数の値にアクセスします。
	const EDITOR_SETTINGS_PATH = "sclib/fit_font_size/"
	const EDITOR_SETTINGS_SECTION = "scale_correction_value/"
	
	# セクション内に保存されるデータです。
	var dic_answer = {}
	dic_answer["Label"] = 0.9
	dic_answer["Button"] = 1.0
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションに保存します。
	# ファイルが存在しない場合は作成し、存在する場合は辞書の要素ごとに上書きします。
	print("save_editor_settings_section_from_dictionary call")
	save_editor_settings_section_from_dictionary(
		EDITOR_SETTINGS_PATH, EDITOR_SETTINGS_SECTION, dic_answer)
	
	return


## load_editor_settings_section_to_dictionary のテスト関数です。
func test_load_editor_settings_section_to_dictionary():
	## 以下の 2 つを組み合わせて、さらにキー名を追加した name で辞書変数の値にアクセスします。
	const EDITOR_SETTINGS_PATH = "sclib/fit_font_size/"
	const EDITOR_SETTINGS_SECTION = "scale_correction_value/"
	
	## セクション内に保存されるデータです。
	var dic_save = {}
	dic_save["Label"] = 0.9
	dic_save["Button"] = 1.0
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションに保存します。
	# ファイルが存在しない場合は作成し、存在する場合は辞書の要素ごとに上書きします。
	print("save_editor_settings_section_from_dictionary call")
	save_editor_settings_section_from_dictionary(
		EDITOR_SETTINGS_PATH, EDITOR_SETTINGS_SECTION, dic_save)
	
	# 取得するキーを設定します。
	var key_array = ["Label", "Button", "OptionButton", "CheckButton"]
	
	# デフォルト値を設定します。
	var initial_values := {}
	initial_values["Label"] = 0.5
	initial_values["OptionButton"] = 0.8
	
	# 例では、 CheckButton はセーブしておらず、デフォルト値も指定しません。
	# OptionButton はセーブしていませんが、デフォルト値を指定しています。
	# Button はセーブしていますが、デフォルト値は指定していません。
	# Label はセーブしていて、デフォルト値も指定しています。
	var dic_answer = {}
	dic_answer["Label"] = 0.9
	dic_answer["Button"] = 1.0
	dic_answer["OptionButton"] = 0.8
	#dic_answer["CheckButton"] は、取得されません。
	
	# 指定した EditorSettings ファイルのセクションを読み込み、辞書として取得します。
	print("load_editor_settings_section_to_dictionary call")
	var dic: Dictionary = load_editor_settings_section_to_dictionary(
		EDITOR_SETTINGS_PATH, EDITOR_SETTINGS_SECTION, key_array, initial_values)
	
	# 保存した辞書の内容と、読み込んだ辞書の内容が等しいことを確認します。
	# 異なる場合は警告を出力します。
	if dic != dic_answer:
		push_warning("study_editor_settings_to_dictionary.gd:" +
			"test_load_sample_dictionary:" +
			"dic != dic_answer")
	
	# デバッグ用。読み込んだ辞書の内容を出力します。
	var str_dic: String = ScUtil.to_pretty_print_string(dic)
	print(str_dic)

	return


## 指定した EditorSettings の path （例：「ユーザ名/アドオン名」）のセクションを辞書型で取得します。
## [param path] と [param section] については [method save_editor_settings_section_from_dictionary] を
## 参照してください。
func load_editor_settings_section_to_dictionary(
	path: String, section: String, key_array: Array, default_values: Dictionary = {}
) -> Dictionary:
	var dic := {}
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# EditorSettings から key_array に指定したキーを base_path に加えた各 name　の値を
	# 戻り値の辞書のキーの値として取得します。
	var editor_settings = EditorInterface.get_editor_settings()
	if editor_settings == null:
		push_error("study_eidotr_settings_by_dictionary.gd:" +
			"load_editor_settings_section_to_dictionary:" +
			"editor_settings == null")
		return dic
	
	var default_keys = default_values.keys()
	# 辞書変数の要素ごとに EditorSettings から値を取得します。
	for key in key_array:
		# name の最後には、辞書変数のキーを追加します。
		var editor_settings_name: String = base_path + key
		
		# 本関数内でデフォルト値を設定していない、かつ、name の設定が存在しない場合は警告を出力します。
		# それ以外は、辞書変数に設定値を格納します。
		if editor_settings.has_setting(editor_settings_name) == false:
			if key in default_keys:
				dic[key] = default_values[key]
			else:
				push_warning("study_eidotr_settings_by_dictionary.gd:" +
					"load_editor_settings_section_to_dictionary:" +
					"editor_settings.has_setting(editr_settings_name) == false, " +
					"editor_settings_name = ", editor_settings_name)
		else:
			dic[key] = editor_settings.get_setting(editor_settings_name)
	
	return dic


## 指定した EditorSettings の path （例：「ユーザ名/アドオン名」）のセクションに、辞書型のデータを保存します。
## 辞書の要素のキーは、EditorSettings.set_settings の name 引数、値は value 引数に対応します。
##
## [param path] と [param section] を連結した base_path に、
## 辞書の要素キーを付け加えた name に対して value を設定します。
##
## [param path] に "user_name/addon_name/" を指定して、
## [param section] に "section_name/" を設定すると
## ユーザ名、アドオン名、セクション名を / で区切った後にキーを加えた name に value を設定します。
func save_editor_settings_section_from_dictionary(
	path: String, section: String, dic: Dictionary) -> void:
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# EditorSettings に dic の各要素を保存します。
	var editor_settings = EditorInterface.get_editor_settings()
	if editor_settings == null:
		push_error("study_eidotr_settings_by_dictionary.gd:" +
			"save_editor_settings_section_from_dictionary:" +
			"editor_settings == null")
		return
	
	# 辞書変数の要素ごとに EditorSettings に保存します。
	for key in dic.keys():
		# name の最後には、辞書変数のキーを追加します。
		var editor_settings_name: String = base_path + key
		editor_settings.set_setting(editor_settings_name, dic[key])
	
	return

  core/variant/variant_utility.cpp:1112 - study_eidotr_settings_by_dictionary.gd:load_editor_settings_section_to_dictionary:editor_settings.has_setting(editr_settings_name) == false, editor_settings_name = sclib/fit_font_size/scale_correction_value/CheckButton
save_editor_settings_section_from_dictionary call
load_editor_settings_section_to_dictionary call
{
	"Label": 0.9,
	"Button": 1,
	"OptionButton": 0.8
}