Godot４ 任意の数のサウンドを同時再生できるGDスクリプトの静的関数の例

extends Node
class_name SCUtil
## ユーティリティ関数を定義します。
##
## SakuraCrowd が作成した関数です。自己責任でご利用ください。

## [b]指定した音声ストリームを１回再生します。[/b][br]
## [br]
## 内部で生成された [AudioStreamPlayer] ノードは [param upper_node] の下位ノードに一時的に追加されます。[br]
## 内部で生成された [AudioStreamPlayer] ノードは finished シグナルにより自身を解放します。[br]
## [param audio_stream] は、あらかじめ load または preload 関数で AudioStream を作成してください。[br]
## [codeblock]
## # 処理が開始される前にメンバ変数に読み込む場合
## @onready var as1: AudioStream = preload("res://sound/Button.wav")
##
## # 関数内などで読み込む場合
## func hoge():
##     var as2: AudioStream = load("res://sound/Hit.wav")
##     AudioStreamOneShotPlay(self, as1)
##     AudioStreamOneShotPlay(self, as2)
##     # 本関数呼び出し時に読み込む場合
##     AudioStreamOneShotPlay(self, load("res://sound/Break.wav"))
##     return
## [/codeblock]
static func AudioStreamOneShotPlay(upper_node: Node, audio_stream: AudioStream) -> void:
	# AudioStreamPlayer ノードを作成して、指定されたノードの下位に一時的に追加します。
	var audio_player: AudioStreamPlayer = AudioStreamPlayer.new()
	upper_node.add_child(audio_player)
	
	# 再生する音声ストリームを設定します。
	audio_player.stream = audio_stream

	# 音声が再生終了した時のシグナルを接続して、自動的に生成したノードを解放します。
	audio_player.connect("finished", audio_player.queue_free)

	# 音を再生します。
	audio_player.play()
	
	return

extends Control

## ブロックにぶつかりブロックを壊した際の効果音を読み込んで保持します。
@onready var audio_stream_break: AudioStream = preload("res://sound/Break.wav")

# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta):
	# マウス左ボタン(クリック) が押された直後の場合
	if Input.is_action_just_pressed("ui_click"):
		print("_process(): マウス左ボタンが押されました。")
		# ボタンの効果音を再生します。
		SCUtil.AudioStreamOneShotPlay(SCUtilGlobal, audio_stream_break)
	return