Godot4 EditorSettingsに追加した設定値の削除のスクリプト例

@tool
extends EditorPlugin

## EditorSettings の「ユーザ名/アドオン名/セクション名/キー」の読み書きを Dictionary 型を用いて行う関数とそのテストです。
## EditorInterface の機能はエディタ上で利用できます。
## EditorSettings の機能を含む関数を実行するために、プラグインとしてこのスクリプトを追加して
## ツールメニュー（「プロジェクト」→「ツール」）から、これが追加したメニューを選択してください。
## 
## EditorSettings のファイルは C:\Users\ユーザ名\AppData\Roaming\Godot\editor_settings-4.3.tres にあります。
## 4.3 の部分はバージョンによって変わります。

## メニューアイテムの表示名です。
const tool_menu_item_name: StringName = "Study EditorSettings By Dictionary"

## プラグインの初期化処理を定義します。
## プラグイン (プロジェクト設定ダイアログ＞プラグイン＞有効) を有効にした直後や、プラグインが有効な状態のプロジェクトを開いた際に呼び出されます。
func _enter_tree():
	# Initialization of the plugin goes here.
	# メニュー「プロジェクト」→「ツール」にサブメニューを追加します。メニュー選択時に、第二引数のメンバ関数を呼び出します。
	add_tool_menu_item(tool_menu_item_name, Callable(self, "_on_menu_item_study_editor_settings_by_dictionary"))
	return


## プラグインの後片付けの処理を定義します。
## プラグインを無効 (プロジェクト設定ダイアログ＞プラグイン＞有効) にした直後や、プラグインが有効な状態でプロジェクトを閉じた際に呼び出されます。
func _exit_tree():
	# Clean-up of the plugin goes here.
	remove_tool_menu_item(tool_menu_item_name)
	return


## プラグインで追加したツールメニューを選択した際に呼び出される関数です。
func _on_menu_item_study_editor_settings_by_dictionary():
	# EditorSettings に追加した独自の設定値を削除します。
	test_erase_editor_settings_section_initial_value_from_dictionary()
	
	return


func test_erase_editor_settings_section_initial_value_from_dictionary():
	# 以下の 2 つを組み合わせて、さらにキー名を追加した name で辞書変数の値にアクセスします。
	const EDITOR_SETTINGS_PATH = "sclib/fit_font_size/"
	const EDITOR_SETTINGS_SECTION = "scale_correction_value/"
	
	# セクション内に保存されるデータです。
	var array_erase_keys = ["Label", "Panel"]
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションの
	# 各設定値の初期値に設定します。
	print("erase_editor_settings_section_initial_value_from_dictionary call")
	erase_editor_settings_section_initial_value_from_dictionary(
		EDITOR_SETTINGS_PATH, EDITOR_SETTINGS_SECTION, array_erase_keys)
	
	return


## EditorSettings の項目を削除します。
## 削除することでエディタが正常に動作しなくなる危険性があるので注意してください。
##　[param path] + [param section ] + [param erase_keys] の各要素で連結した文字列
## の name に一致する項目を削除します。
func erase_editor_settings_section_initial_value_from_dictionary(
	path: String, section: String, erase_keys: Array = []
) -> void:
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# EditorSettings から key_array に指定したキーを base_path に加えた各 name　の値を
	# 戻り値の辞書のキーの値として取得します。
	var editor_settings = EditorInterface.get_editor_settings()
	if editor_settings == null:
		push_error("study_eidotr_settings_by_dictionary.gd:" +
			"erase_editor_settings_section_initial_value_from_dictionary:" +
			"editor_settings == null")
		return
	
	# 辞書変数の要素ごとに EditorSettings から値を取得します。
	for key in erase_keys:
		# name の最後には、辞書変数のキーを追加します。
		var editor_settings_name: String = base_path + key
		print("erase_editor_settings_section_initial_value_from_dictionary, editor_settings_name = ", editor_settings_name)
		# name と同じ項目があれば、それを削除します。
		if editor_settings.has_setting(editor_settings_name) == true:
			# 指定した name の設定値を削除します。
			editor_settings.erase(editor_settings_name)
			print(editor_settings_name, " を EditorSettings から削除しました。")
		else:
			print(editor_settings_name, " は EditorSettings にありませんでした。")
	return

erase_editor_settings_section_initial_value_from_dictionary call
erase_editor_settings_section_initial_value_from_dictionary, editor_settings_name = sclib/fit_font_size/scale_correction_value/Label
sclib/fit_font_size/scale_correction_value/Label を EditorSettings から削除しました。
erase_editor_settings_section_initial_value_from_dictionary, editor_settings_name = sclib/fit_font_size/scale_correction_value/Panel
sclib/fit_font_size/scale_correction_value/Panel は EditorSettings にありませんでした。

	var array_erase_keys = ["Label", "Button"]

erase_editor_settings_section_initial_value_from_dictionary call
erase_editor_settings_section_initial_value_from_dictionary, editor_settings_name = sclib/fit_font_size/scale_correction_value/Label
sclib/fit_font_size/scale_correction_value/Label は EditorSettings にありませんでした。
erase_editor_settings_section_initial_value_from_dictionary, editor_settings_name = sclib/fit_font_size/scale_correction_value/Button
sclib/fit_font_size/scale_correction_value/Button を EditorSettings から削除しました。