Godot4 確率を指定してランダムに複数シーンの中からノードを作成

# お宝（シーン）のリスト
var list_scene_otakara:Array[PackedScene]
# お宝（シーン）の出現確率
var list_prob_scene_otakara:Array

func _ready():
	# list_scene_otakara と list_prob_scene_otakara の設定
	list_scene_otakara.append(preload("res://otakara_coin.tscn"))
	list_prob_scene_otakara.append(0.91)
	list_scene_otakara.append(preload("res://otakara_ruby.tscn"))
	list_prob_scene_otakara.append(0.03)
	list_scene_otakara.append(preload("res://otakara_emerald.tscn"))
	list_prob_scene_otakara.append(0.03)
	list_scene_otakara.append(preload("res://otakara_sapphire.tscn"))
	list_prob_scene_otakara.append(0.03)

# 指定された確率に応じて、複数のお宝の中からランダムに決めたお宝のノードを作成して返します。
func create_otakara() ->RigidBody2D:
	# 全てのお宝の出現確率の合計値です。
	var total_list_prob_scene_otakara = 0
	# total_list_prob_scene_otakara を求めます。
	for prob in list_prob_scene_otakara:
		total_list_prob_scene_otakara += prob

	# 0 ~ total_list_prob_scene_otakara の間からランダムに値を取得します。
	var random_value:float = randf_range(0, total_list_prob_scene_otakara)

	# 各お宝の出現確率を足していき、 random_value の範囲内にあるお宝の要素番号を得ます。
	var tmp_total_list_prob_scene_otakara = 0
	var index = 0
	for prob in list_prob_scene_otakara:
		tmp_total_list_prob_scene_otakara += prob
		if random_value <= tmp_total_list_prob_scene_otakara:
			break
		index += 1
	
	# 確率に従いランダムに選択された要素番号のお宝のシーンを使って、ノードを作成して返します。
	var selected_scene = list_scene_otakara[index]
	var created_otakara:RigidBody2D = selected_scene.instantiate()
	return created_otakara