Godot4 プロジェクト設定に保存した独自の項目の値を辞書変数に得る実装例

@tool
extends EditorPlugin

## ProjectSettings の「ユーザ名/アドオン名/セクション名/キー」の読み書きを Dictionary 型を用いて行う関数とそのテストです。
## EditorInterface の機能はエディタ上で利用できます。
## ProjectSettings の機能を含む関数を実行するために、プラグインとしてこのスクリプトを追加して
## ツールメニュー（「プロジェクト」→「ツール」）から、これが追加したメニューを選択してください。

## 追加するメニューアイテムの表示名です。
const tool_menu_item_name: StringName = "Study ProjectSettings By Dictionary"
## メニューアイテムに追加するサブメニューアイテムの項目名と ID の配列です。
const tool_submenu_item_info_array = [
	{"name": "Save", "id": 0},
	{"name": "Set Initial Value", "id": 1},
	{"name": "Load", "id": 2},
	{"name": "Clear", "id": 3},
]
## サブメニューのリソースです。
var submenu: PopupMenu = null

## テストでアクセスする ProjectSettings の name の要素です。
## テストでは、 EDITOR_SETTINGS_PATH ＋ EDITOR_SETTINGS_SECTION + key を name とします。
const PROJECT_SETTINGS_PATH = "sclib/fit_font_size/"
const PROJECT_SETTINGS_SECTION = "scale_correction_value/"


## プラグインの初期化処理を定義します。
## プラグイン (プロジェクト設定ダイアログ＞プラグイン＞有効) を有効にした直後や、プラグインが有効な状態のプロジェクトを開いた際に呼び出されます。
func _enter_tree():
	if submenu == null:
		# サブメニュー用のポップアップメニューに項目名とその ID を追加します。
		submenu = PopupMenu.new()
		for info in tool_submenu_item_info_array:
			submenu.add_item(info.name, info.id)
		# 選択されたシグナル発生時に呼び出す関数を設定します。
		submenu.id_pressed.connect(_on_submenu_id_pressed)
		# ツールメニュー(「プロジェクト」→「ツール」)にメニューアイテムとそのサブメニューを追加します。
		add_tool_submenu_item(tool_menu_item_name, submenu)
	
	return


## プラグインの後片付けの処理を定義します。
## プラグインを無効 (プロジェクト設定ダイアログ＞プラグイン＞有効) にした直後や、プラグインが有効な状態でプロジェクトを閉じた際に呼び出されます。
func _exit_tree():
	# ツールメニュー(「プロジェクト」→「ツール」)に追加したメニューアイテムを削除します。
	remove_tool_menu_item(tool_menu_item_name)
	# サブメニューのリソースを解放します。
	if submenu != null:
		submenu.queue_free()
		submenu = null
	return


## プラグインで追加したツールメニューのサブメニューを選択した際に呼び出される関数です。
## [param id] は、選択されたサブメニューの項目の ID です。
func _on_submenu_id_pressed(id):
	print("_on_submenu_id_pressed called. id = ", id)
	print(tool_submenu_item_info_array[id].name, " pressed.")
	
	# id が指すツールメニューのサブメニューに対応した処理を実行します。
	match id:
		0:	# Save
			test_save_editor_settings_section_from_dictionary()
		1:	# Set Initial Value
			test_set_editor_settings_section_initial_value_from_dictionary()
		2:	# Load
			test_load_project_settings_section_to_dictionary()
		3:	# Clear
			test_erase_project_settings_section_from_dictionary()
		_:
			push_warning("id is unknown.")
	return

## [method save_project_settings_section_from_dictionary］ のテスト関数です。
func test_save_editor_settings_section_from_dictionary():
	# セクション内に保存されるデータです。
	var dic_save = {}
	dic_save["Label"] = 0.9
	dic_save["Button"] = 1.0
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションに保存します。
	# ファイルが存在しない場合は作成し、存在する場合は辞書の要素ごとに上書きします。
	print("save_project_settings_section_from_dictionary call")
	save_project_settings_section_from_dictionary(
		PROJECT_SETTINGS_PATH, PROJECT_SETTINGS_SECTION, dic_save)
	
	return


## 指定した ProjectSettings の path （例：「ユーザ名/アドオン名」）のセクションに、辞書型のデータを保存します。
## 辞書の要素のキーは、EditorSettings.set_settings の name 引数、値は value 引数に対応します。
##
## [param path] と [param section] を連結した base_path に、
## 辞書の要素キーを付け加えた name に対して value を設定します。
##
## [param path] に "user_name/addon_name/" を指定して、
## [param section] に "section_name/" を設定すると
## ユーザ名、アドオン名、セクション名を / で区切った後にキーを加えた name に value を設定します。
func save_project_settings_section_from_dictionary(
	path: String, section: String, dic: Dictionary) -> void:
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# 辞書変数の要素ごとに EditorSettings に保存します。
	for key in dic.keys():
		# name の最後には、辞書変数のキーを追加します。
		var project_settings_name: String = base_path + key
		ProjectSettings.set_setting(project_settings_name, dic[key])
	
	return


func test_erase_project_settings_section_from_dictionary():
	# セクション内に保存されるデータです。
	var array_erase_keys = ["Label", "Button"]
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションの
	# 各設定値の初期値に設定します。
	print("erase_project_settings_section_from_dictionary call")
	erase_project_settings_section_from_dictionary(
		PROJECT_SETTINGS_PATH, PROJECT_SETTINGS_SECTION, array_erase_keys)
	
	return


## ProjectSettings の項目を削除します。
## 削除することでエディタが正常に動作しなくなる危険性があるので注意してください。
##　[param path] + [param section ] + [param erase_keys] の各要素で連結した文字列
## の name に一致する項目を削除します。
func erase_project_settings_section_from_dictionary(
	path: String, section: String, erase_keys: Array = []
) -> void:
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# 辞書変数の要素ごとに EditorSettings から値を取得します。
	for key in erase_keys:
		# name の最後には、辞書変数のキーを追加します。
		var project_settings_name: String = base_path + key
		print("erase_project_settings_section_from_dictionary, project_settings_name = ", project_settings_name)
		# name と同じ項目があれば、それを削除します。
		if ProjectSettings.has_setting(project_settings_name) == true:
			# 指定した name の設定値を削除します。
			ProjectSettings.set_setting(project_settings_name, null)
			print(project_settings_name, " を ProjectSettings から削除しました。")
		else:
			print(project_settings_name, " は ProjectSettings にありませんでした。")
	return


## [method set_editor_settings_section_initial_value_from_dictionary] のテスト関数です。
func test_set_editor_settings_section_initial_value_from_dictionary():
	# セクション内に保存されるデータです。
	var dic_initial = {}
	dic_initial["Label"] = 0.98
	dic_initial["Button"] = 0.95
	
	# 辞書のデータ群を、指定した EditorSettings ファイルのセクションの
	# 各設定値の初期値に設定します。
	print("set_editor_settings_section_initial_value_from_dictionary call")
	set_editor_settings_section_initial_value_from_dictionary(
		PROJECT_SETTINGS_PATH, PROJECT_SETTINGS_SECTION, dic_initial)
	
	return


## ProjectSettings の項目の初期値を指定します。
## これは ProjectSettings の Revert ボタンが押されたときなどに用いられます。
## 存在しない項目については処理しません。
func set_editor_settings_section_initial_value_from_dictionary(
	path: String, section: String, initial_values: Dictionary = {}
) -> void:
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	# 辞書変数の要素ごとに EditorSettings から値を取得します。
	for key in initial_values.keys():
		# name の最後には、辞書変数のキーを追加します。
		var project_settings_name: String = base_path + key
		print("set_initial_values, project_settings_name = ", project_settings_name)
		if ProjectSettings.has_setting(project_settings_name) == true:
			# 初期値を設定します。
			ProjectSettings.set_initial_value(project_settings_name, initial_values[key])
			print("set_initial_value project_settings_name = ", project_settings_name, 
			", initial_value = ", initial_values[key])
		else:
			print("set_initial_value project_settings_name = ", project_settings_name, 
			" は存在しません。 ")
	
	return


## load_project_settings_section_to_dictionary のテスト関数です。
func test_load_project_settings_section_to_dictionary():
	# 取得するキーを設定します。
	var key_array = ["Label", "Button", "OptionButton", "CheckButton"]
	
	# デフォルト値を設定します。
	var default_values := {}
	default_values["Label"] = 0.5
	default_values["OptionButton"] = 0.8
	
	# 指定した EditorSettings ファイルのセクションを読み込み、辞書として取得します。
	print("load_editor_settings_section_to_dictionary call")
	var dic: Dictionary = load_project_settings_section_to_dictionary(
		PROJECT_SETTINGS_PATH, PROJECT_SETTINGS_SECTION, key_array, default_values)
	
	# 読み込んだ辞書の内容を出力します。
	var str_dic: String = ScUtil.to_pretty_print_string(dic)
	print(str_dic)

	return


## 指定した ProjectSettings の path （例：「ユーザ名/アドオン名」）のセクションを辞書型で取得します。
## [param path] と [param section] については [method save_project_settings_section_from_dictionary] を
## 参照してください。
func load_project_settings_section_to_dictionary(
	path: String, section: String, key_array: Array, default_values: Dictionary = {}
) -> Dictionary:
	var dic := {}
	
	# 設定を保存する name のキーの１つ前までの階層の文字列を作成します。
	var base_path := path + section
	
	var default_keys = default_values.keys()
	# 辞書変数の要素ごとに EditorSettings から値を取得します。
	for key in key_array:
		# name の最後には、辞書変数のキーを追加します。
		var project_settings_name: String = base_path + key
		
		# 本関数内でデフォルト値を設定していない、かつ、name の設定が存在しない場合は警告を出力します。
		# それ以外は、辞書変数に設定値を格納します。
		if ProjectSettings.has_setting(project_settings_name) == false:
			if key in default_keys:
				dic[key] = default_values[key]
			else:
				push_warning("study_project_settings_by_dictionary.gd:" +
					"load_project_settings_section_to_dictionary:" +
					"ProjectSettings.has_setting(project_settings_name) == false, " +
					"project_settings_name = ", project_settings_name)
		else:
			dic[key] = ProjectSettings.get_setting(project_settings_name)
	
	return dic

	var dic_save = {}
	dic_save["Label"] = 0.9
	dic_save["Button"] = 1.0

_on_submenu_id_pressed called. id = 0
Save pressed.
save_project_settings_section_from_dictionary call

scale_correction_value/Button を設定

[sclib]

fit_font_size/scale_correction_value/Label=0.9
fit_font_size/scale_correction_value/Button=0.777

  core/variant/variant_utility.cpp:1112 - study_project_settings_by_dictionary.gd:load_project_settings_section_to_dictionary:ProjectSettings.has_setting(project_settings_name) == false, project_settings_name = sclib/fit_font_size/scale_correction_value/CheckButton
_on_submenu_id_pressed called. id = 2
Load pressed.
load_editor_settings_section_to_dictionary call
{
	"Label": 0.9,
	"Button": 0.77700000000186,
	"OptionButton": 0.8
}

print("Raw: ", "%.20f" % float_value)